StockFetcher Forums · Filter Exchange · A NEW ^VIX TRADING SYSTEM<< 1 ... 44 45 46 47 48 ... 49 >>Post Follow-up
Kevin_in_GA
4,599 posts
msg #133782
- Ignore Kevin_in_GA		 1/17/2017 4:46:27 PM

The VIX is correlated with the markets, but the price of the ETFs is strongly influenced by contango. Look at today - the ^VIX is up 5.7% but VXX is down 0.7% and XIV is up 0.6%. If these truly mirrored the spot index, this would not happen. But with the contango level at 19% right now, XIV is moving up and VXX is moving down. You can also see that the ^SPX has traded basically flat for the past month while XIV has moved up more than 17% and VXX has dropped the same amount. Again - contango.
Kevin_in_GA
4,599 posts
msg #133884
- Ignore Kevin_in_GA		 1/25/2017 7:03:30 PM

Just a heads up - the system triggered 6 new Long ^VIX signals tonight, with 2 more already in play. 8 of 10 filters indicating a short term increase in volatility. Trade carefully though - contango still favors shorting.
pthomas215
1,251 posts
msg #134050
- Ignore pthomas215		 2/4/2017 4:21:41 PM

i thought this is a pretty cool website for contango.

https://vixcontango.com



four
5,087 posts
msg #134071
- Ignore four		 2/6/2017 12:21:35 AM

http://www.arrowfunds.com/files/DDF/Highlights%20-%20Contango%20and%20Cash.pdf

Contango
mahkoh
1,065 posts
msg #134423
- Ignore mahkoh		 2/20/2017 4:22:04 PM

For those interested; composite long and short filters

Fetcher[
symlist(vxx)
/*ENTRY CONDITIONS*/
set{arooncrossbelow, count(ind(^vix, aroon up(11)) crossed below ind(^vix, aroon down(11)), 1)}
set{ma3belowma60, count(ind(^vix, MA(3)) below ind(^vix, ma(60)), 1)}
set{entry1, arooncrossbelow * ma3belowma60}

/*EXIT CONDITIONS*/
set{exit1, count(ind(^vix, aroon up(11)) crossed above ind(^vix, aroon down(11)), 1)}


add column entry1
add column exit1

/*ENTRY CONDITIONS*/
set{closebelowenvl, count(ind(^vix, close) crossed below ind(^vix, Lower SMA Envelope(25,6.0)), 1)}
set{stochcross, count(ind(^vix, Stochastic %K(3,4)) above ind(^vix, Stochastic %D(3,4,5)), 1)}
set{entry2, closebelowenvl * stochcross}

/*EXIT CONDITIONS*/
set{exit2, count(ind(^vix, close) crossed above ind(^vix, Upper SMA Envelope(25,6.0)), 1)}


add column entry2
add column exit2

/*ENTRY CONDITIONS*/
set{entry1a, count(ind(^VIX,close) reached a new 15 day low, 1)}
set{mom9low, ind(^vix, momentum(9) 15 day low)}
set{entry1b, count(ind(^vix, momentum(9)) above mom9low, 1)}
set{entry11, entry1a * entry1b}
set{entry22, count(ind(^vix, pdi(14)) below ind(^vix, mdi(14)), 1)}
set{entry3, entry11 * entry22}

/*EXIT CONDITIONS*/
set{exit11, count(ind(^vix, close) reached a new 15 day high, 1)}
set{mom9high, ind(^vix, momentum(9)) 15 day high}
set{exit22, count(ind(^vix, momentum(9)) below mom9high, 1)}
set{exit33, exit11 * exit22}
set{exit44, count(ind(^vix, pdi(14)) above ind(^vix, mdi(14)), 1)}
set{exit3, exit33 + exit44}

add column entry3
add column exit3

/*ENTRY CONDITIONS*/
set{stochcross1, count(ind(^vix, Stochastic %K(9,4)) crossed below ind(^vix, Stochastic %D(9,4,9)), 1)}
set{arooncross, count(ind(^vix, aroon up(15)) below ind(^vix, aroon down(15)), 1)}
set{entry4, arooncross * stochcross1}

/*EXIT CONDITIONS*/
set{exit4, count(ind(^vix, Stochastic %K(9,4)) crossed above ind(^vix, Stochastic %D(9,4,9)), 1)}


add column entry4
add column exit4

/*ENTRY CONDITIONS*/
set{belowbbl, count(ind(^vix, close) below ind(^vix, lower Bollinger Band(13,0.5)), 1)}
set{moneyflow, count(ind(^vix, mfi(20)) below 85, 1)}
set{entry1aa, count(ind(^VIX,close) reached a new 60 day low, 1)}
set{mom60low, ind(^vix, momentum(9) 60 day low)}
set{entry1bb, count(ind(^vix, momentum(9)) above mom60low, 1)}
set{entry101, entry1aa * entry1bb}
set{entry202, belowbbl * moneyflow}
set{entry5, entry101 * entry202}

/*EXIT CONDITIONS*/
set{abovebbl, count(ind(^vix, close) above ind(^vix, lower Bollinger Band(13,0.5)), 1)}
set{moneyflow2, count(ind(^vix, mfi(20)) above 85, 1)}
set{exit5, abovebbl + moneyflow2}

add column entry5
add column exit5

/*ENTRY CONDITIONS*/
set{entry111, count(ind(^vix, pdi(16)) crossed below ind(^vix, mdi(16)), 1)}
set{pbanddiff, ind(^vix, Upper Projection Band(15)) - ind(^vix, Lower Projection Band(15))}
set{pbandma, cma(pbanddiff, 15)}
set{entry222, count(pbanddiff below pbandma, 1)}
set{entry6, entry111 * entry222}

/*EXIT CONDITIONS*/
set{exit6, count(ind(^vix, pdi(16)) crossed above ind(^vix, mdi(16)), 1)}}

add column entry6
add column exit6

/*ENTRY CONDITIONS*/
set{entry1111, count(ind(^vix, cci(19)) crossed below -119, 1)}
set{entry2222, count(ind(^vix, ppo(3,60)) above 0, 1)}
set{entry7, entry1111 * entry2222}

/*EXIT CONDITIONS*/
set{exit1111, count(ind(^vix, cci(19)) crossed above -119, 1)}
set{exit2222, count(ind(^vix, ppo(3,60)) below 0, 1)}
set{exit7, exit1111 + exit2222}

add column entry7
add column exit7

set{x,entry1 + entry2}
set{x1,x + entry3}
set{x2,x1 + entry4}
set{x3,x2 + entry5}
set{x4,x3 + entry6}
set{compentry,x4 + entry7}
add column compentry


set{y,exit1 + exit2}
set{y1,y + exit3}
set{y2,y1 + exit4}
set{y3,y2 + exit5}
set{y4,y3 + exit6}
set{compexit,y4 + exit7}
add column compexit
add column ind(^VIX,close)
]



Fetcher[

symlist(xiv)
/*ENTRY CONDITIONS*/
set{entry11, count(ind(^vix, smi(3,2,2)) above 32,1)}
SET{PJO_UP, COUNT(ind(^vix, projection oscillator(5)) GAINED MORE THAN 0% OVER THE LAST 5 DAYS,1)}
SET{PJO_DN, COUNT(ind(^vix, projection oscillator(5)) DROPPED MORE THAN 0% OVER THE LAST 5 DAYS,1)}

SET{MA3_UP, COUNT(ind(^vix, MA(3)) GAINED MORE THAN 0% OVER THE LAST 5 DAYS,1)}
SET{MA3_DN, COUNT(ind(^vix, MA(3)) DROPPED MORE THAN 0% OVER THE LAST 5 DAYS,1)}

SET{POS_DIV, PJO_UP * MA3_DN}
SET{NEG_DIV, PJO_DN * MA3_UP}

set{entry22, count(NEG_DIV above 0.5, 1)}
set{entry1, entry11 * entry22}

/*EXIT CONDITIONS*/
set{exit1, count(POS_DIV above 0.5, 1)}

add column entry1
add column exit1

/*ENTRY CONDITIONS*/
set{entry1a, count(ind(^VIX, close) reached a new 15 day high, 1)}
set{prochigh, ind(^vix, proc(5,1)) 15 day high}
set{entry1b, count(ind(^vix, proc(5,1)) below prochigh, 1)}
set{entry1c, entry1a * entry1b}

set{entry2c, count(ind(^vix, trix(5)) above cma(ind(^vix, trix(5)),25), 1)}
set{entry2, entry1c * entry2c}

/*EXIT CONDITIONS*/
set{exit1a, count(ind(^VIX, close) reached a new 15 day low, 1)}
set{proclow, ind(^vix, proc(5,1)) 15 day low}
set{exit1b, count(ind(^vix, proc(5,1)) above proclow, 1)}
set{exit12, entry1a * entry1b}

set{exit21, count(ind(^vix, trix(5)) below cma(ind(^vix, trix(5)),25), 1)}
set{exit2, exit21 + exit12}

add column entry2
add column exit2

/*ENTRY CONDITIONS*/
set{entry1a1, count(ind(^vix, close) crossed above cma(ind(^vix, close),15), 1)}
set{entry2a1, count(ind(^vix, close) above ind(^vix, upper sma envelope(15,7)), 1)}
set{entry3, entry1a1 * entry2a1}

/*EXIT CONDITIONS*/

set{exit3, count(ind(^vix, close) crossed below cma(ind(^vix, close),15), 1)}

add column entry3
add column exit3

/*ENTRY CONDITIONS*/
set{entry1b1, count(ind(^vix, trix(9)) above ind(^vix, trix(9)) 1 day ago, 1)}
set{entry2b1, count(ind(^vix, smi(5,4,4)) above 30, 1)}
set{entry4, entry1b1 * entry2b1}

/*EXIT CONDITIONS*/

set{exit1b1, count(ind(^vix, trix(9)) below ind(^vix, trix(9)) 1 day ago, 1)}
set{exit2b1, count(ind(^vix, smi(5,4,4)) below -32, 1)}
set{exit4, exit1b1 + exit2b1}

add column entry4
add column exit4

/*ENTRY CONDITIONS*/
set{entry1c1, count(ind(^vix, Price Oscillator(3,25)) crossed above 0, 1)}

SET{SMI_UP, COUNT(ind(^vix, SMI(3,4,4)) GAINED MORE THAN 5% OVER THE LAST 19 DAYS,1)}
SET{SMI_DN, COUNT(ind(^vix, SMI(3,4,4)) DROPPED MORE THAN 5% OVER THE LAST 19 DAYS,1)}
SET{MA3_UP1, COUNT(ind(^vix, MA(3)) GAINED MORE THAN 5% OVER THE LAST 19 DAYS,1)}
SET{MA3_DN1, COUNT(ind(^vix, MA(3)) DROPPED MORE THAN 5% OVER THE LAST 19 DAYS,1)}
SET{POS_DIV1, SMI_UP * MA3_DN1}
SET{NEG_DIV1, SMI_DN * MA3_UP1}

set{entry2c2, count(NEG_DIV1 above 0.5, 1)}
set{entry5, entry1c1 * entry2c2}

/*EXIT CONDITIONS*/
set{exit5, count(ind(^vix, Price Oscillator(3,25)) crossed below 0, 1)}

add column entry5
add column exit5

/*ENTRY CONDITIONS*/
set{lrientry, ind(^vix, lri(20)) * 0.97}
set{entry1d1, count(ind(^vix, close) crossed above lrientry, 1)}
set{entry2d1, count(ind(^vix, close) below ind(^vix, lower Bollinger Band(10,0.5)), 1)}

set{entry6, entry1d1 * entry2d1}

/*EXIT CONDITIONS*/
set{exit6, count(ind(^vix, close) crossed below lrientry, 1)}

add column entry6
add column exit6

set{x,entry1 + entry2}
set{x1,x + entry3}
set{x2,x1 + entry4}
set{x3,x2 + entry5}
set{compentry,x3 + entry6}
add column compentry


set{y,exit1 + exit2}
set{y1,y + exit3}
set{y2,y1 + exit4}
set{y3,y2 + exit5}
set{compexit,y3 + exit6}
add column compexit
add column ind(^VIX,close)
]
davesaint86
726 posts
msg #134443
- Ignore davesaint86		 2/21/2017 7:58:20 PM

What does it mean when there is a

davesaint86
726 posts
msg #134444
- Ignore davesaint86		 2/21/2017 7:59:06 PM

What does it mean when one of the filters has both a 1 in the entry and exit?
c1916
77 posts
msg #134448
- Ignore c1916		 2/21/2017 10:49:16 PM

FWIW, the much simpler IFT Trigger for volatility has signals an entry to TVIX or UVXY for tomorrow. It has been ages since there's been a buy sign on the simple trigger for volatility.

Not my filter.

symlist(tvix,uvxy,xiv)
average Volume(30) ABOVE 2000000
PRICE is below EMA(13)
SMI(5,3,1) has been increasing for 2 days
% Day Change more than 2%
RSI(10) has been increasing for the past 2 days


draw MACD Fast Line(12,26,9) and MACD Slow Line(12,26,9)
draw RSI(10)

draw cci(61) line at 0
draw cci(61) line at 150
draw cci(10) line at 0

DRAW WEEKLY IFT(2,1)
DRAW WEEKLY IFT(2,1) LINE AT .90
DRAW WEEKLY IFT(2,1) LINE AT -.90
mahkoh
1,065 posts
msg #134473
- Ignore mahkoh		 2/22/2017 2:11:12 PM

I don't think there should be simultaneous entries and exits on the same filter, but I just took what Kevin made and wrapped it all together. There are some filters where the column returns 2, like short exit No 4 today. This can be repaired by changing the last line into:

set{exit4a, exit1b1 + exit2b1}
set{exit4,count(exit4a above 0.5,1)}



tennisplayer2
210 posts
msg #134485
- Ignore tennisplayer2		 2/22/2017 10:10:54 PM

First time, I got no signals at all. Totally out. Is that what y'all are getting? Thanks in advance.
StockFetcher Forums · Filter Exchange · A NEW ^VIX TRADING SYSTEM<< 1 ... 44 45 46 47 48 ... 49 >>Post Follow-up

StockFetcher Tools
Filter Editor
My Filters
Watch Lists
Chart+
Find Similar Stocks
Shared Lists
Popular Resources
StockFetcher Forums
Indicator List
Filter Phrases
Examples
Site Search
Sector/Industry List
Usage Guide
Support
Contact Us
Support Home

Subscriber
Subscriber Benefits
Settings
Chart
Results
MyFilters
*** Disclaimer *** StockFetcher.com does not endorse or suggest any of the securities which are returned in any of the searches or filters. They are provided purely for informational and research purposes. StockFetcher.com does not recommend particular securities. StockFetcher.com, Vestyl Software, L.L.C. and involved content providers shall not be liable for any errors or delays in the content, or for any actions taken based on the content.


Copyright 2022 - Vestyl Software L.L.C.•Terms of Service | License | Questions or comments? Contact Us
EOD Data sources: DDFPlus & CSI Data Quotes delayed during active market hours. Delay times are at least 15 mins for NASDAQ, 20 mins for NYSE and Amex. Delayed intraday data provided by DDFPlus


This site is protected by reCAPTCHA and the Google Privacy Policy and Terms of Service apply.